Usc2017nsp

第 04 週 (05/31) Arduino Ethernet Shield實際連線到Server-1 (3)

積土成山，風雨興焉；積水成淵，蛟龍生焉；積善成德，而神明自得，聖心備焉。故不積蹞步，無以至千里；不積小流，無以成江海。騏驥一躍，不能十步；駑馬十駕，功在不舍。

• Ethernet與PubSubClient函式的使用
• Ethernet程式設計
• PubSubClient程式設計
• 功能測試
• 接線參考
  

Ethernet與PubSubClient函式的使用

• 在程式碼一開始時載入SPI.h、Ethernet.h、PubSubClient.h

// including the library
#include<SPI.h>
#include<Ethernet.h>
#include<PubSubClient.h>
#include<dht11.h>

//	Module variable
dht11	DhtSensor;
int	PsSensor;

Ethernet程式設計

• 新增變數存放MAC位址與IP資料

// including the library
#include<SPI.h>
#include<Ethernet.h>
#include<PubSubClient.h>
#include<dht11.h>

//	Ethernet variable
byte	Mac[] = {0xDE ,0xAD ,0xBE ,0xEF ,0xFE ,0xED};
byte	Ip[] = {192 ,168 ,1 ,200};
EthernetClient  client;

//	Module variable
dht11	DhtSensor;
int	PsSensor;

• 程式初始化時設定Ethernet Shield連線時所使用的MAC與IP(剛剛新增的變數)

// initial
void setup(){
	//	Serial Baudrate
	Serial.begin(115200);
	
	//	Ethernet communication
	Ethernet.begin(Mac ,Ip);
	
	//	Setting I/O mode
	pinMode(5 ,OUTPUT);
	pinMode(6 ,OUTPUT);
	pinMode(7 ,OUTPUT);
	
	digitalWrite(5 ,LOW);
	digitalWrite(6 ,LOW);
	digitalWrite(7 ,LOW);
}

• 以localIP()功能顯示Ethernet Shield所取得的IP

// initial
void setup(){
	//	Serial Baudrate
	Serial.begin(115200);
	
	//	Ethernet communication
	Ethernet.begin(Mac ,Ip);
	
	//	Setting I/O mode
	pinMode(5 ,OUTPUT);
	pinMode(6 ,OUTPUT);
	pinMode(7 ,OUTPUT);
	
	digitalWrite(5 ,LOW);
	digitalWrite(6 ,LOW);
	digitalWrite(7 ,LOW);
	
	//	Show local IP
	Serial.print("Local IP : ");
	Serial.println(Ethernet.localIP());
}

PubSubClient程式設計

• 新增變數存放MQTT Server IP資料

// including the library
#include<SPI.h>
#include<Ethernet.h>
#include<PubSubClient.h>
#include<dht11.h>

//	Ethernet variable
byte	Mac[] = {0xDE ,0xAD ,0xBE ,0xEF ,0xFE ,0xED};
byte	Ip[] = {192 ,168 ,1 ,200};
EthernetClient  client;

//	MQTT variable
int	ServerPort = 1883;
byte	MqttServer[] = {192 ,168 ,1 ,252};
PubSubClient  MqttClient(client);

//	Module variable
dht11	DhtSensor;
int	PsSensor;

• 程式初始化時設定目標Server的IP與Port

// initial
void setup(){
	//	Serial Baudrate
	Serial.begin(115200);
	
	//	Ethernet communication
	Ethernet.begin(Mac ,Ip);
	
	//	MQTT communication
	MqttClient.setServer(MqttServer ,ServerPort);
	
	//	Setting I/O mode
	pinMode(5 ,OUTPUT);
	pinMode(6 ,OUTPUT);
	pinMode(7 ,OUTPUT);
	
	digitalWrite(5 ,LOW);
	digitalWrite(6 ,LOW);
	digitalWrite(7 ,LOW);
	
	//	Show local IP
	Serial.print("Local IP : ");
	Serial.println(Ethernet.localIP());
}

• 主程式中判斷若連線成功，就向MQTT Server傳送Sensor的資料

// main loop
void loop(){
	char	msg[100] = " ";

	//	Running at connect server
	if(MqttClient.connect("SensorClient")){
		//	Read sensor data
		DhtSensor.read(A0);
		PsSensor = analogRead(A1);
		
		//  Show value
		Serial.print("Humidity : ");
		Serial.println(DhtSensor.humidity);

		sprintf(msg ,"{\"Humidity\":%4d}" ,DhtSensor.humidity);
		MqttClient.publish("Sensor",msg);
	  
		Serial.print("Temperature : ");
		Serial.println(DhtSensor.temperature);
		
		sprintf(msg ,"{\"Temperature\":%4d}" ,DhtSensor.temperature);
		MqttClient.publish("Sensor",msg);
		
		Serial.print("Pressure : ");
		Serial.println(PsSensor);
		
		sprintf(msg ,"{\"Pressure\":%4d}" ,PsSensor);
		MqttClient.publish("Sensor",msg);
		
		//	Test output
		if(DhtSensor.humidity <= 30){
			digitalWrite(7 ,HIGH);
			//  Alarm msg
			Serial.println("Humidity Alarm. ");
			sprintf(msg ,"{\"Humidity\":%4d}" ,DhtSensor.humidity);
			MqttClient.publish("Alarm",msg);
			
		}else{
			digitalWrite(7 ,LOW);	
		}
		
		if(DhtSensor.temperature <= 25){
			digitalWrite(6 ,HIGH);
			//  Alarm msg
			Serial.println("Temperature Alarm. ");
			sprintf(msg ,"{\"Temperature\":%4d}" ,DhtSensor.temperature);
			MqttClient.publish("Alarm",msg);
			
		}else{
			digitalWrite(6 ,LOW);
		}

		if(PsSensor >= 10){
			digitalWrite(5 ,HIGH);
			//  Alarm msg
			Serial.println("Pressure Alarm. ");
			sprintf(msg ,"{\"Pressure\":%4d}" ,PsSensor);
			MqttClient.publish("Alarm",msg);
			
		}else{
			digitalWrite(5 ,LOW);
		}
	}
	
	Serial.println("");
	
	//	Every second run one turn
	delay(1000);
}

• 提示-注意有坑
  1. Server IP、Arduino IP
• 程式參考影片
  

功能測試

• 開啟mosquitto接收來自Arduino的訊息
• 開啟MQTTLens確認Arduino的訊息是否正確傳到Server上

作業

將課堂做完的成果錄影後貼至FB社團內

備註

• 參考範例Etherduino.zip